#------------------------------------------------------------------------
# FWR/3
#------------------------------------------------------------------------

FWR3 =    
    StandardMessageIdentification
    AWBConsignmentDetail
    SenderReference;

# Standard Message Identification
# -------------------------------
StandardMessageIdentification =
    "FWR/3" 
    CRLF;

# AWB Consignment Details
# -----------------------
AWBConsignmentDetail =    
    AWBIdentification 
    CRLF;

AWBIdentification =    
    DE112_AirlinePrefix 
    Hyphen
    DE113_AWBSerialNumber;

# REF - Sender Reference
# ----------------------
SenderReference =
    DE103_LineIdentifier_REF
    Slant
    (
        (Slant
         [REF_RequestingOfficeFileReference]
         REF_RequestingParticipantIdentification)
        /
        (REF_RequestingOfficeMessageAddress
         [Slant REF_RequestingOfficeFileReference])
    )
    CRLF;

REF_RequestingOfficeMessageAddress =
    DE313_AirportCityCode
    DE107_OfficeFunctionDesignator
    DE308_CompanyDesignator;
    
REF_RequestingOfficeFileReference =
    DE117_FileReference;
    
REF_RequestingParticipantIdentification =
    Slant
    DE319_ParticipantIdentifier
    Slant
    DE320_ParticipantCode
    Slant
    DE313_AirportCityCode;

# Data Elements
# -------------

DE101_StandardMessageIdentifier         = 3Alpha;
DE103_LineIdentifier_REF                = "REF";
DE107_OfficeFunctionDesignator          = 2Mixed;
DE112_AirlinePrefix                     = 3Numeric;
DE113_AWBSerialNumber                   = 8Numeric;
DE117_FileReference                     = 1*15Text;
DE124_MessageTypeVersionNumber          = 1*3Numeric;
DE308_CompanyDesignator                 = 2Mixed;
DE313_AirportCityCode                   = 3Alpha;
DE319_ParticipantIdentifier             = 1*3Mixed;
DE320_ParticipantCode                   = 1*17Mixed;

# Types
# -----
CRLF    = (CR LF) / LF; 
CR      = %x0D;
LF      = %x0A;
Slant   = "/";
Hyphen  = "-";
Alpha   = %x41-5A;
Numeric = %x30-39;
Decimal = %x30-39 / ".";
Mixed   = Alpha / Numeric;
Text    = %x41-5A / %x30-39 / "." / "-" / " ";

#------------------------------------------------------------------------
# eof
#------------------------------------------------------------------------